Deploy a Micronaut application to AWS Lambda Java 11 Runtime

Learn how to distribute a Micronaut application to AWS Lambda 11 Runtime

Authors: Sergio del Amo

Micronaut Version: 2.5.0

1. Getting Started

In this guide we are going to create a Micronaut app written in Groovy.

2. What you will need

To complete this guide, you will need the following:

Some time on your hands
A decent text editor or IDE
JDK 1.8 or greater installed with JAVA_HOME configured appropriately

3. Solution

We recommend that you follow the instructions in the next sections and create the app step by step. However, you can go right to the completed example.

Download and unzip the source

4. Writing the App

Create an app using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide --feature=aws-lambda --build=gradle --lang=groovy

If you don’t specify the --build argument, Gradle is used as a build tool.
If you don’t specify the --lang argument, Java is used as a language.

If you use Micronaut Launch, add aws-lambda feature.

The previous command creates a Micronaut app with the default package example.micronaut in a folder named micronautguide.

The generated application contains a BookController. It responds to POST request to /.

src/main/groovy/example/micronaut/BookController.groovy

package example.micronaut
import io.micronaut.http.annotation.Body
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Post
import javax.validation.Valid
import groovy.transform.CompileStatic

@CompileStatic
@Controller
class BookController {

    @Post
    BookSaved save(@Valid @Body Book book) {
        BookSaved bookSaved = new BookSaved()
        bookSaved.name = book.name
        bookSaved.isbn = UUID.randomUUID().toString()
        bookSaved
    }
}

The class is defined as a controller with the @Controller annotation mapped to the path /
The @Post annotation is used to map HTTP request to / to the the save method.
Add the @Valid annotation to any method parameter’s object which requires validation.

The controller’s method parameter is a Book object:

src/main/groovy/example/micronaut/Book.groovy

package example.micronaut
import io.micronaut.core.annotation.NonNull
import io.micronaut.core.annotation.Introspected
import javax.validation.constraints.NotBlank
import groovy.transform.CompileStatic

@CompileStatic
@Introspected
class Book {

    @NonNull
    @NotBlank
    String name
}

Annotate the class with @Introspected to generate the Bean Metainformation at compile time.

It returns a BookSaved object:

src/main/groovy/example/micronaut/BookSaved.groovy

package example.micronaut;
import io.micronaut.core.annotation.NonNull
import io.micronaut.core.annotation.Introspected
import javax.validation.constraints.NotBlank
import groovy.transform.CompileStatic

@CompileStatic
@Introspected
class BookSaved {

    @NonNull
    @NotBlank
    String name


    @NonNull
    @NotBlank
    String isbn
}

Annotate the class with @Introspected to generate the Bean Metainformation at compile time.

The generated tests illustrates how the code works when the lambda gets invoked:

src/test/groovy/example/micronaut/BookControllerSpec.groovy

package example.micronaut
import com.amazonaws.serverless.proxy.internal.testutils.AwsProxyRequestBuilder
import com.amazonaws.serverless.proxy.internal.testutils.MockLambdaContext
import com.amazonaws.serverless.proxy.model.AwsProxyRequest
import com.amazonaws.serverless.proxy.model.AwsProxyResponse
import com.amazonaws.services.lambda.runtime.Context
import com.fasterxml.jackson.databind.ObjectMapper
import io.micronaut.http.HttpHeaders
import io.micronaut.http.HttpMethod
import io.micronaut.http.HttpStatus
import io.micronaut.http.MediaType
import spock.lang.Specification
import spock.lang.Shared
import spock.lang.AutoCleanup
import io.micronaut.function.aws.proxy.MicronautLambdaHandler

class BookControllerSpec extends Specification {

    @Shared
    @AutoCleanup
    MicronautLambdaHandler handler = new MicronautLambdaHandler()

    @Shared
    Context lambdaContext = new MockLambdaContext()

    @Shared
    ObjectMapper objectMapper = handler.applicationContext.getBean(ObjectMapper)

    void "test save Book"() {
        given:
        Book book = new Book()
        book.name = "Building Microservices"
        String json = objectMapper.writeValueAsString(book)

        when:
        AwsProxyRequest request = new AwsProxyRequestBuilder("/", HttpMethod.POST.toString())
                .header(HttpHeaders.CONTENT_TYPE, MediaType.APPLICATION_JSON)
                .body(json).build()
        AwsProxyResponse response = handler.handleRequest(request, lambdaContext)

        then:
        HttpStatus.OK.code == response.statusCode
        response.body

        when:
        BookSaved bookSaved = objectMapper.readValue(response.body, BookSaved)

        then:
        bookSaved.name == book.name
        bookSaved.isbn
    }
}

When you instantiate the Handler, the application context starts.
Remember to close your application context when you end your test. You can use your handler to obtain it.
You don’t invoke the controller directly. Instead, your handler receives a AWS Proxy Request event which it is routed transparently to your controller.

5. Testing the Application

To run the tests:

$ ./gradlew test
$ open build/reports/tests/test/index.html

6. Lambda

Create a Lambda Function. As a runtime, select Java 11 (Correto).

6.1. Upload Code

Create an executable jar including all dependencies:

$ ./gradlew assemble

Upload it:

6.2. Handler

As Handler, set:

io.micronaut.function.aws.proxy.MicronautLambdaHandler

6.3. Test

You can test it easily. As Event Template use apigateway-aws-proxy to get you started:

{
  "body": "{\"name\": \"Building Microservices\"}",
  "resource": "/",
  "path": "/",
  "httpMethod": "POST",
  "isBase64Encoded": false,
  "queryStringParameters": {},
  "multiValueQueryStringParameters": {},
  "pathParameters": {},
  "stageVariables": {},
  ...
}

You should see a 200 response:

7. Next steps

Explore more features with Micronaut Guides.

8. Help with Micronaut

Object Computing, Inc. (OCI) sponsored the creation of this Guide. A variety of consulting and support services are available.

Meet the Team.

Table of Contents