Creating your first Micronaut app

Learn how to create a Hello World Micronaut app with a controller and a functional test.

Authors: Iván López, Sergio del Amo

Micronaut Version: 2.5.0

1. Getting Started

In this guide we are going to create a Micronaut app written in Groovy.

2. What you will need

To complete this guide, you will need the following:

Some time on your hands
A decent text editor or IDE
JDK 1.8 or greater installed with JAVA_HOME configured appropriately

3. Solution

We recommend that you follow the instructions in the next sections and create the app step by step. However, you can go right to the completed example.

Download and unzip the source

4. Writing the App

Create an app using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide --build=gradle --lang=groovy

If you don’t specify the --build argument, Gradle is used as a build tool.
If you don’t specify the --lang argument, Java is used as a language.

The previous command creates a Micronaut app with the default package example.micronaut in a folder named micronautguide.

4.1. Application

Application.groovy is used when running the application via Gradle or via deployment. You can also run the main class directly within your IDE if it is configured correctly.

src/main/groovy/example/micronaut/Application.groovy

package example.micronaut

import io.micronaut.runtime.Micronaut
import groovy.transform.CompileStatic

@CompileStatic
class Application {
    static void main(String[] args) {
        Micronaut.run(Application, args)
    }
}

4.2. Controller

In order to create a microservice that responds with "Hello World" you first need a controller.

Create a Controller:

src/main/groovy/example/micronaut/HelloController.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.http.annotation.Produces
import io.micronaut.http.MediaType

@CompileStatic
@Controller("/hello") (1)
class HelloController {
    @Get("/") (2)
    @Produces(MediaType.TEXT_PLAIN) (3)
    String index() {
        "Hello World" (4)
    }
}

1	The class is defined as a controller with the @Controller annotation mapped to the path `/hello`
2	The @Get annotation is used to map the index method to all requests that use an HTTP GET
3	By default a Micronaut’s response uses `application/json` as `Content-Type`. We are returning a String not a JSON object. Because of that, we set it to `text/plain`.
4	A String "Hello World" is returned as the result

4.3. Test

Create a test which verifies that when you do a GET request to /hello you get Hello World as a response:

src/test/groovy/example/micronaut/HelloControllerSpec.groovy

package example.micronaut

import io.micronaut.http.HttpRequest
import io.micronaut.http.client.RxHttpClient
import io.micronaut.http.client.annotation.Client
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import spock.lang.Specification

import javax.inject.Inject

@MicronautTest (1)
class HelloControllerSpec extends Specification {

    @Inject
    @Client("/")  (2)
    RxHttpClient client

    void "test hello world response"() {
        when:
        HttpRequest request = HttpRequest.GET('/hello')  (3)
        String rsp = client.toBlocking().retrieve(request)

        then:
        rsp == "Hello World"
    }
}

1	Annotate the class with `@MicronautTest` so Micronaut will initialize the application context and the embedded server.
2	Inject the `RxHttpClient` bean. It is used the execute an HTTP call to the controller.
3	Creating HTTP Requests is easy thanks to Micronaut’s fluid API.

5. Testing the Application

To run the tests:

$ ./gradlew test
$ open build/reports/tests/test/index.html

6. Running the Application

To run the application use the ./gradlew run command which will start the application on port 8080.

7. Next steps

8. Help with Micronaut

Object Computing, Inc. (OCI) sponsored the creation of this Guide. A variety of consulting and support services are available.

Meet the Team.

Table of Contents